Comparar Medias en SPSS

Copyright Fco.J.Herrero y Marcelino Cuesta
Dpto. Psicología
Universidad de Oviedo (Tutorial:DPAM#96.1)
Actualizado al SPSS(7.52) en Diciembre de 1997

    Este fichero contiene un tutorial hipermedia (fase experimental) perteneciente al área de Metodología de las Ciencias del Comportamiento (Dpto. de Psicologia en la Universidad de Oviedo).

    Se presenta de forma intuitiva una introducción general al proceso de contraste de medias. Haciendo especial hincapié en los aspectos conceptuales y obviando los aspectos más formales. Es de particular interés para los alumnos de metodología, sobre todo para aquellos que en este momento cursan la asignatura de Análisis de Datos en Psicología.

Introducción

    La prueba de hipótesis sobre de igualdad de medias es uno de las aplicaciones más usadas por los investigadores en el campo de la Psicología. El uso de software estadístico, como es el caso del SPSS, ofrece una variedad de procedimientos capaces de desempeñar de forma correcta este tipo de comparaciones.
     Varios de estos procedimientos son bastante simples, diseñados expresamente para el manejo de este tipo de problemas, mientras otros son más generales, y necesariamente más complejo.
     Para poder emplear adecuadamente cualquiera de estas opciones, los usuarios necesitan estar familiarizados con la estructura de los datos requerido por SPSS.

    El SPSS, como la mayoría de los programas estadísticos, trabaja inicialmente sobre datos rectangulares (matrices de datos), donde las filas de la matriz rectangular representan los casos, mientras las columnas denotan las variables.
    De esta forma, la pregunta esencial que debemos resolver cuando nosotros vamos comparar dos o más medias es si estas representan a procesos de muestreos independientes o relacionados.
    La segunda pregunta que deberemos resolver es si se quiere comparar las medias de dos o más de dos grupos de casos.

La estructuración para Muestreos Independientes

    Si la comparación deseada involucra a temas o datos independientes de muestreo, la estructura general seguirá el esquema general de una o más variables de agrupación para identificar qué tipo de datos representa, junto con los valores para la variable sobre la que nosotros deseamos comparar los grupos citados. Por ejemplo, supongamos que intentamos medir las diferencias en rendimiento académico de dos grupos de sujetos formados atendiendo a la condición del sexo. La estructuración apropiada de datos para una comparación de dos medias en estos dos grupos de casos sería:

data list free/ GRUPO Y.
begin data.
1	4.50
1	4.70
1	5.20
1	5.70
1	6.30
2	5.80
2	6.70
2	7.30
2	8.20
2	8.70
end data.

    En otras palabras SPSS necesita un indicador de como hay que agrupar cada caso (en nuestro ejemplo esto es realizado por la variable llamada GRUPO), así como también el valor de la variable medida(en el ejemplo Y). Una vez que los datos son introducidos de acuerdo a este formato, cualquier de los procedimientos siguientes pueden usarse para obtener una prueba de la hipótesis nula sobre la igualdad de los dos grupos en la población:

T-TEST GROUPS=GRUPO /VAR=Y.

MEANS Y BY GRUPO /STATISTICS=ANOVA.

ONEWAY Y BY GRUPO.

ANOVA Y BY GRUPO(1,2).

MANOVA Y BY GRUPO(1,2).

    Para situaciones en que hay tres o más grupos se sigue la misma estructura, excepto que habrá más de dos valores para la variable GRUPO, y teniendo en cuenta además que no podemos usar el T-TEST como procedimiento para comparar más de dos de medias a un mismo tiempo.
    Por ejemplo, supongamos el siguiente caso:

data list free/ GRUPO Y.
begin data.
1	3.10
1	2.60
1	3.70
1	4.20
2	5.10
2	6.30
2	5.40
2	6.10
3	7.30
3	7.90
3	8.20
3	9.00
end data.

    Los procedimientos en SPSS que podriamos utilizar serían:

MEANS Y BY GRUPO/STATISTICS=ANOVA.

ONEWAY Y BY GRUPO.

ANOVA Y BY GRUPO(1,3).

MANOVA Y BY GRUPO(1,3).

La estructuración para Muestreos Emparejados o Dependientes

    Suponga que en vez de querer comparar las medias de dos o más grupos de casos independientes, nosotros ahora queremos hacer comparaciones entre las medidas tomadas sobre los mismos sujetos bajo diferentes o las mismas condiciones. A estas medidas repetidas en el tiempo, nosotros la identificaremos en este ejemplo como el factor TIEMPO.
    La estructuración de datos es ahora diferente. Lo que representamos es una variable analizada en dos momentos distintos, y la forma de expresarlo es como si tuviesemos dos variables medidas para cada caso. Por ejemplo, podemos llamarlas TIEMPO1 y TIEMPO2, resultando una estructuración de datos semejante a la siguiente:

data list free / TIEMPO1 TIEMPO2.
begin data.
4.50	4.90
4.70	5.20
4.30	6.20
4.60	5.00
5.60	7.30
6.00	8.30
end data.

    Los procedimientos MEANS, ONEWAY y ANOVA no son útiles a la hora de manejar dete tipo de datos. La forma adecuada de indicarlo a hora es:

T-TEST PAIRS=TIEMPO1 TIEMPO2.

RELIABILITY VARIABLES=TIEMPO1 TIEMPO2
 /STATISTICS=ANOVA.

MANOVA TIEMPO1 TIEMPO2
 /WSFACTORS=TIEMPO(2).

    Si nos movemos en una comparación que involucre a más de dos medias relacionadas, no podríamos usar el procedimiento: T-TEST.

La estructura de los datos para más de dos medias relacionadas sería semejante a:

data list free/ TIEMPO1 TIEMPO2 TIEMPO3.
begin data.
4.50	4.90	6.20
4.70	5.20	6.40
4.30	6.20	7.10
4.60	5.00	7.00
5.60	7.30	8.10
6.00	8.30	9.30
end data.

    Siendo la sintaxis equivalente a:

RELIABILITY VARIABLES=TIEMPO1 TIEMPO2 TIEMPO3
 /STATISTICS=ANOVA.

MANOVA TIEMPO1 TIEMPO2 TIEMPO3
 /WSFACTORS=TIEMPO(3).

     La estructura de los datos para dos medias relacionadas o más y una o más independientes sería equivalente a:

data list free/ GRUPO TIEMPO1 TIEMPO2.
begin data.
1	4.90	6.20
1	5.20	6.40
1	6.20	7.10
1	5.00	7.00
2	7.30	8.10
2	8.30	9.30
2	6.10	7.30
2	6.20	7.40
end data.

     La única solución es utilizar la información dada por MANOVA, y esta información única será estrictamente válida bajo algunas suposiciones bastante severas. Siendo su sintaxis equivalente a:

MANOVA TIEMPO1 TIEMPO2 BY GRUPO(1,2)
 /WSFACTORS=TIEMPO(2).