*SPSS-WIN(6.01).
* Medidas repetidas de variables categóricas via WLS.
*---------------------------------------------------.
*Ejemplo(Manual SPSS-pg:321)
*Los sujetos consumen 3 drogas siendo evaluados como
* reacción favorable(1) o desfavorable(0).

data list free/d1 d2 d3 count.
begin data.
1 1 1  6
1 1 0 16
1 0 1  2
1 0 0  4
0 1 1  2
0 1 0  4
0 0 1  6
0 0 0  6
end data.

matrix.
*Base de datos
* [a] matriz de configuración de respuestas.
get a /variables=d1 d2 d3.
get count /variables=count.

* Algoritmo matricial.
compute n=csum(count).
* [p] proporcion de casos in la configuración de respuestas.
compute p=count/n.
*1-Totales marginales.
* [f] vector conteniendo total marginal, siendo la variable dependiente.
compute f=t(a)*p.
*debug*.
*print f/title '???vector <f>'.
*2-Matriz de covarianzas de proporciones.
compute vp=(mdiag(p)-p*t(p))/n.
*debug*.
*print vp/title '???Matriz de covarianzas de proporciones'.
*3-Matriz de covarianzas de marginales.
* [vf] matriz de covarianza asintótica de f.
compute vf=t(a)*vp*a.
* [x] matriz de diseño.
compute x={1, 1, 0;
           1, 0, 1;
           1,-1,-1}.
*4-Matriz de covarianzas de estimaciones.
* [vb] matriz de covarianza asintótica de b.
compute vb=inv(t(x)*inv(vf)*x).
*5-Estimación de parámetros.
* [b] vector conteniendo los parámetros estimados.
compute b=vb*t(x)*inv(vf)*f.
compute l={0, 1, 0;
           0, 0, 1}.
*6-Test de homogeneidad.
* [qchi] valor del test X-2 sobre homogeneidad.
compute qchi=t(l*b)*inv(l*vb*t(l))*(l*b).
* [qsig] significación del test anterior.
compute qsig=1-chicdf(qchi,2).
*7-Test de coeficientes.
* [bchi] test X-2 de los parámetros.
compute bchi=(b&*b)&/diag(vb).
* [bsig] significación del test anterior.
compute bsig=1-chicdf(bchi,1).
* Impresión de resultados.
print f/format=f12.6/title 'Totales marginales'/space=newpage.
print vf/format=f14.8/title 'Covarianza asintótica de totales marginales'.
print {qchi,qsig}/format=f12.6/title 'Test de homogeneidad'/
    clabels='chi Sq.' 'Prob.'.
print {b,bchi,bsig}/format=f12.6/title 'Parámetros'/
    clabels='Estimadores' 'Chi Sq.' 'Prob.'.
print vb /format=f14.8/title='Covarianza asintótica de la estimación de parámetros'.
end matrix.